/\*

Programs to analyze a crossover with two covariates.

The analyses are done with change scores, to allow comparison  
 with the spreadsheet for post-only crossovers at Sportscience.

Includes two tricks to make programming simpler.

Changes from the first program to include the tricks are shown tracked;

\*/

\*import the dataset **crossover two predictors wide data.xlsx** as **import**;

data cross;

set import;

array a TrtA--TrtD;

do over a;

a=100\*log(a);

end;

DeltaCA=TrtC-TrtA;

X2=TrtA; \*for adjusting change scores involving TrtA as baseline;

Mean=1; \*for the first trick;

\*proc print;run;

ods noproctitle;

ods graphics / imagemap=on;

title "Analyzing change scores in a crossover with two predictors";

proc mixed data=cross plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

model DeltaCA=X1 X2/residual ddfm=sat s;

estimate "Predicted means @...";

estimate "X1=8.91 X2=598.5" int 1 X1 8.91 X2 598.5/cl alpha=0.1;

estimate "X1=6 X2=590" int 1 X1 6 X2 590/cl alpha=0.1;

estimate "Effects of delta predictors:";

estimate "X1 x1" X1 1/cl alpha=0.1;

estimate "X1 x5.97" X1 5.97/cl alpha=0.1;

estimate "X2 x11.6" X2 11.6/cl alpha=0.1;

run;

/\*

The trick here is to use lsmeans to get the mean value without having to

specify an estimate statement with the mean values of the covariates.

I have kept the first estimate statement to show it gives the same answer.

\*/

title "Analyzing change scores in a crossover with two predictors";

title2 "illustrating a trick with use of Mean as a class variable";

proc mixed data=cross plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Mean;

model DeltaCA=Mean X1 X2/residual ddfm=sat s noint;

lsmeans Mean/cl alpha=0.1;

estimate "Predicted means @...";

estimate "X1=8.91 X2=598.5" Mean 1 X1 8.91 X2 598.5/cl alpha=0.1;

estimate "X1=6 X2=590" Mean 1 X1 6 X2 590/cl alpha=0.1;

estimate "Effects of delta predictors:";

estimate "X1 x1" X1 1/cl alpha=0.1;

estimate "X1 x5.97" X1 5.97/cl alpha=0.1;

estimate "X2 x11.6" X2 11.6/cl alpha=0.1;

run;

/\*

Here is the second trick, which uses proc standard to set the means and SD

of predictor variables to 0 and 1 respectively. The estimate statements are

then much simpler to get mean effects, but of course the slopes (per unit

of the predictor) are correspondingly much more difficult and not attempted

here. If you want the slopes, run the mixed model without proc standard first.

\*/

proc standard data=cross mean=0 std=0.5 out=cross1;

var X1 X2;

title "Analyzing change scores in a crossover with two predictors";

title2 "illustrating a trick with proc standard";

proc mixed data=cross1 plots(only)=StudentPanel(conditional) alpha=0.1;

model DeltaCA=X1 X2/residual ddfm=sat s;

estimate "Predicted means @...";

estimate "X1=mean X2=mean" int 1/cl alpha=0.1;

estimate "X1=mean-1SD X2=mean" int 1 X1 -0.5/cl alpha=0.1;

estimate "X1=mean+1SD X2=mean" int 1 X1 0.5/cl alpha=0.1;

estimate "Effects of delta predictors:";

estimate "X1 x2SD" X1 1/cl alpha=0.1;

estimate "X2 x2SD" X2 1/cl alpha=0.1;

\*not easy to get simple slopes;

run;